New Scans to Run via SF 5% Weekly TRO

5% A WEEK FILTER (BASED ON TRO'S CROCK POT)
courtesy of TRO and Kevin_in_GA

/*MEASURE THE DIFFERENCE FROM WEEKLY OPEN TO WEEKLY HIGH*/
set{whiop, weekly high - weekly open}
set{Long_Profit, whiop / weekly open }

/*DETERMINE THE FREQUENCY THAT 5% IS ACHIEVED OVER MULTIPLE TIME FRAMES*/
set{5_1wk, count(Long_Profit > .05,1)}
set{5_4wk, count(Long_Profit > .05,4)}
set{5_13wk, count(Long_Profit > .05,13)}

/*APPLY WEIGHTING FACTORS*/
set{var1,5_4wk*0.5} /*WEIGHT 4 WK AVERAGE AT 2X*/
set{var2,5_13wk*0.07692} /*WEIGHT 13 WK AVERAGE AT 1X*/

/*CREATE A WEIGHTED SUMMATION OF STOCK PERFORMANCE (MAX SCORE = 3)*/
set{reward,var1+var2}

/*DETERMINE THE RISK OF TRIPPING A 10% STOP LOSS*/
set{wloss, weekly open - weekly low}
set{max_loss, wloss / weekly open}

/*DETERMINE THE FREQUENCY THAT A 10% STOP LOSS IS TRIPPED OVER MULTIPLE TIME FRAMES*/
set{loss_1wk, count(max_loss > .10,1)}
set{loss_4wk, count(max_loss > .10,4)}
set{loss_13wk, count(max_loss > .10,13)}

/*APPLY WEIGHTING FACTORS*/
set{var11,loss_4wk*0.5} /*WEIGHT 4 WK AVERAGE AT 2X*/
set{var21,loss_13wk*0.07692} /*WEIGHT 13 WK AVERAGE AT 1X*/

/*CREATE A WEIGHTED SUMMATION OF RISK (MAX SCORE = 3)*/
set{risk,var11+var21}
set{performance,reward/risk}

add column performance
add column reward {reward}
add column risk {risk}
add column 5_4wk {4 wk reward}
add column loss_4wk {4 wk risk}
add column 5_13wk {13 wk reward}
add column loss_13wk {13 wk risk}

/*SCREEN FOR THE STRONGEST CANDIDATES*/
weekly open is above 1
average volume(90) above 500000
and reward is greater than 2.8

and draw 5_1wk
and draw loss_1wk on plot 5_1wk
and do not draw reward

sort column 6 descending

chart-display is weekly